UBASIC/Scripts/CanonA640: Interval Video

Interval Video

Written for/on: Canon A640

Also works on: Other Canon AXXX (Not tested)

Interval Video by Johan Van Barel (http://www.vanbarel.tk)

This script takes a number of videos of a given length (Min, Sec) at a given interval (Min, Sec). For long intervals you should disable the Power Saving options of your camera. This can be done in the <ALT> menu. In the Miscellaneous Stuff menu item set the Disable LCD Off value to Script, so the display won't turn off while in <ALT> mode or while a script is running.

Documentation/Help (save as a small IntervalVideo.txt" file to your /CHDK/SCRIPTS/ folder)

---

Select Movie mode on your Canon A640

Parameters:

• Number of Videos (Default=2)
• Video Length (Min) (Default=0)
• Video Length (Sec) (Default=10)
• Interval (Min) (Default=0)
• Interval (Sec) (Default=10)
• Initial Delay (Sec) (Default=1)

---

Script Code (save as "IntervalVideo.bas" to your /CHDK/SCRIPTS/ folder)

rem Johan Van Barel 07-07-2007
rem Interval-Video for Canon A640

@title Interval Video
@param a Number of Videos
@default a 2

@param b Video length (Min) 
@default b 0
@param c Video length (Sec) 
@default c 10

@param d Interval (Min)
@default d 0
@param e Interval (Sec)
@default e 10

@param f Initial Delay (Sec)
@default f 1

if a<2 then let a=2
if b<0 then let b=0
if c<0 then let c=0
if d<0 then let d=0
if e<0 then let e=0
if f<0 then let f=0

t=60000*b+1000*c
i=60000*d+1000*e

if t<1000 then let t=1000
if i<2000 then let i=2000

print "Videos:"; a
print "Total Time:", ((t*a)+(i*(a-1)))/60000; "Min", ((t*a)+(i*(a-1)))%60000/1000; "Sec"

sleep f*1000

print "Video 1 of", a
click "shoot_full"
click "shoot_full"
sleep t
click "shoot_full"

for s=2 to a
    print "Wait",d;"Min",e;"Sec"
    sleep i

    print "Video", s, "of", a
    click "shoot_full"
    sleep t
    click "shoot_full"
next s

end